在这篇文章中，探讨一种计算在至少一列中满足规定条件的行数的解决方案，示例工作表如下图1所示，其中详细列出了各个国家在不同年份废镍的出口水平。

图1

假设我们希望确定2004年出口总额大于或等于1000的国家的数量，可以使用公式：

=COUNTIF(B2:B14,”>=1000″)

或者：

=SUMPRODUCT(N(B2:B14>=1000))

如果希望计算2004年和2005年有多少个国家的出口总额大于或等于1000，可以使用公式：

=COUNTIFS(B2:B14,”>=1000″,C2:C14,”>=1000″)

或者：

=SUMPRODUCT(N(B2:B14>=1000),N(C2:C14>=1000))

现在，如果我们希望计算2004年和2005年的数据中至少有一个满足此标准的国家数量呢?由于数据较少，我们可以从工作表中清楚地标出满足条件的数据，如下图2所示。

图2

显然，“标准的”COUNTIF(S)公式结构不能满足要求，因为我们必须确保不要重复计数。实际上，在这种情况下，大多数人倾向于使用SUMPRODUCT函数，即：

=SUMPRODUCT(N((B2:B14>=1000)+(C2:C14>=1000)>0))

但是，如果选择的话，我们可以使用COUNTIFS函数构造解决方案，因为考虑到该函数相对于SUMPRODUCT函数的优势(通常，COUNTIFS函数引用整列的能力更有效)，在某些情况下这可能是值得的。

回到我们刚才要解决的问题，实际上要考虑下列3种互斥情形：

1)2004年的数字> =1000，而2005年的数字<1000

2)2004年的数字是<1000，而2005年的数字是> =1000

3)2004年的数字> =1000，而2005年的数字> = 1000

然后，将每种情形统计的结果相加。转换成Excel公式为：

=COUNTIFS(B2:B14,”>=1000″,C2:C14,”>=1000″)+COUNTIFS(B2:B14,”>=1000″,C2:C14,”<1000″)+COUNTIFS(B2:B14,”<1000″,C2:C14,”>=1000″)

这个公式既不优雅也不简洁。但是，我们可以将其缩写为：

=SUM(COUNTIFS(B2:B14,{“>=”,”>=”,”<“}&1000,C2:C14,{“>=”,”<“,”>=”}&1000))

这样，成功地实现了基于COUNTIFS函数的解决方案来代替通常的SUMPRODUCT函数公式构造。

下面，考虑希望得出的结果涉及的列数不只是两列，甚至可能是多列的情况。例如，假设要确定从2004年到2012年每年至少有一个数字大于或等于1000的国家的数量。如下图3所示，我们可以在工作表中标出满足条件的数据，除了2个国家外，其他11个国家都满足条件。

图3

此时，我们根本无法按照上述方法构造与SUMPRODUCT函数解决方案等效的COUNTIFS构造。使用SUMPRODUCT函数的公式：

=SUMPRODUCT(N((B2:B14>=1000)+(C2:C14>=1000)+(D2:D14>=1000)+(E2:E14>=1000)+(F2:F14>=1000)+(G2:G14>=1000)+(H2:H14>=1000)+(I2:I14>=1000)+(J2:J14>=1000)>0))

可得出正确的结果11。然而，公式显得太笨拙了，如果考虑的列数不是9而是30，那会怎样!

幸运的是，由于示例中列区域是连续的，因此可以在单个表达式中查询整个区域(B2：J14)，随后适当地操纵这个结果数组。

这个解决方案的数组公式如下：

=SUM(N(MMULT(N(B2:J14>1000),TRANSPOSE(COLUMN(B2:J14)^0))>0))

公式中，比较区域中的每个元素是否大于或等于1000：

B2:J14>1000

结果是包含以下布尔值的数组：

{TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;FALSE,FALSE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;FALSE,FALSE,TRUE,TRUE,FALSE,TRUE,TRUE,TRUE,TRUE;FALSE,FALSE,FALSE,FALSE,FALSE,TRUE,TRUE,TRUE,FALSE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;FALSE,TRUE,FALSE,FALSE,FALSE,FALSE,TRUE,FALSE,TRUE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,FALSE,TRUE;FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE;TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE,TRUE}

使用N函数强制转换成数字：

N(B2:J14>1000)

得到：

{1,1,1,1,1,1,1,1,1;0,0,1,1,1,1,1,1,1;0,0,1,1,0,1,1,1,1;0,0,0,0,0,1,1,1,0;1,1,1,1,1,1,1,1,1;1,1,1,1,1,1,1,1,1;0,1,0,0,0,0,1,0,1;1,1,1,1,1,1,1,1,1;0,0,0,0,0,0,0,0,0;1,1,1,1,1,1,1,1,1;1,1,1,1,1,1,1,0,1;0,0,0,0,0,0,0,0,0;1,1,1,1,1,1,1,1,1}

现在，为了计算每一行中1的数量，我们使用MMULT。并且，由于上述数组(一个13行乘9列的数组)包含9列，因此我们用来形成乘积的矩阵的行数必须等于该数组的列数。这样，形成第二个矩阵的公式构造为：

TRANSPOSE(COLUMN(B2:J14)^0)

转换为：

TRANSPOSE({2,3,4,5,6,7,8,9,10}^0)

转换为：

TRANSPOSE({1,1,1,1,1,1,1,1,1})

由于必须确保由9个1组成的数组由9行组成，因此使用TRANSPOSE函数来转换：

{1;1;1;1;1;1;1;1;1}

这样，就可以将上述两个数组传递给MMULT函数，因此：

MMULT(N(B2:J14>1000),TRANSPOSE(COLUMN(B2:J14)^0))

转换为：

MMULT({1,1,1,1,1,1,1,1,1;0,0,1,1,1,1,1,1,1;0,0,1,1,0,1,1,1,1;0,0,0,0,0,1,1,1,0;1,1,1,1,1,1,1,1,1;1,1,1,1,1,1,1,1,1;0,1,0,0,0,0,1,0,1;1,1,1,1,1,1,1,1,1;0,0,0,0,0,0,0,0,0;1,1,1,1,1,1,1,1,1;1,1,1,1,1,1,1,0,1;0,0,0,0,0,0,0,0,0;1,1,1,1,1,1,1,1,1},{1;1;1;1;1;1;1;1;1})

得到：

{9;7;6;3;9;9;3;9;0;9;8;0;9}

然后，确定该数组中哪些元素大于0，然后将结果求和。因此，公式：

=SUM(N(MMULT(N(B2:J14>1000),TRANSPOSE(COLUMN(B2:J14)^0))>0))

转换为：

=SUM(N({9;7;6;3;9;9;3;9;0;9;8;0;9}>0))

转换为：

=SUM(N({TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE}))

转换为：

=SUM({1;1;1;1;1;1;1;1;0;1;1;0;1})

结果为：

11

如果不想使用数组公式，可以使用下面的公式替换：

=SUM(N(MMULT(N(B2:J14>1000),ROW(INDEX(A:A,1):INDEX(A:A,COLUMNS(B2:J14)))^0)>0))